home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 26 / Cream of the Crop 26.iso / os2 / octa209s.zip / octave-2.09 / libcruft / lapack / zunmbr.f < prev    next >
Text File  |  1996-07-19  |  8KB  |  251 lines
  1.       SUBROUTINE ZUNMBR( VECT, SIDE, TRANS, M, N, K, A, LDA, TAU, C,
  2.      $                   LDC, WORK, LWORK, INFO )
  3. *
  4. *  -- LAPACK routine (version 2.0) --
  5. *     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
  6. *     Courant Institute, Argonne National Lab, and Rice University
  7. *     September 30, 1994
  8. *
  9. *     .. Scalar Arguments ..
  10.       CHARACTER          SIDE, TRANS, VECT
  11.       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
  12. *     ..
  13. *     .. Array Arguments ..
  14.       COMPLEX*16         A( LDA, * ), C( LDC, * ), TAU( * ),
  15.      $                   WORK( LWORK )
  16. *     ..
  17. *
  18. *  Purpose
  19. *  =======
  20. *
  21. *  If VECT = 'Q', ZUNMBR overwrites the general complex M-by-N matrix C
  22. *  with
  23. *                  SIDE = 'L'     SIDE = 'R'
  24. *  TRANS = 'N':      Q * C          C * Q
  25. *  TRANS = 'C':      Q**H * C       C * Q**H
  26. *
  27. *  If VECT = 'P', ZUNMBR overwrites the general complex M-by-N matrix C
  28. *  with
  29. *                  SIDE = 'L'     SIDE = 'R'
  30. *  TRANS = 'N':      P * C          C * P
  31. *  TRANS = 'C':      P**H * C       C * P**H
  32. *
  33. *  Here Q and P**H are the unitary matrices determined by ZGEBRD when
  34. *  reducing a complex matrix A to bidiagonal form: A = Q * B * P**H. Q
  35. *  and P**H are defined as products of elementary reflectors H(i) and
  36. *  G(i) respectively.
  37. *
  38. *  Let nq = m if SIDE = 'L' and nq = n if SIDE = 'R'. Thus nq is the
  39. *  order of the unitary matrix Q or P**H that is applied.
  40. *
  41. *  If VECT = 'Q', A is assumed to have been an NQ-by-K matrix:
  42. *  if nq >= k, Q = H(1) H(2) . . . H(k);
  43. *  if nq < k, Q = H(1) H(2) . . . H(nq-1).
  44. *
  45. *  If VECT = 'P', A is assumed to have been a K-by-NQ matrix:
  46. *  if k < nq, P = G(1) G(2) . . . G(k);
  47. *  if k >= nq, P = G(1) G(2) . . . G(nq-1).
  48. *
  49. *  Arguments
  50. *  =========
  51. *
  52. *  VECT    (input) CHARACTER*1
  53. *          = 'Q': apply Q or Q**H;
  54. *          = 'P': apply P or P**H.
  55. *
  56. *  SIDE    (input) CHARACTER*1
  57. *          = 'L': apply Q, Q**H, P or P**H from the Left;
  58. *          = 'R': apply Q, Q**H, P or P**H from the Right.
  59. *
  60. *  TRANS   (input) CHARACTER*1
  61. *          = 'N':  No transpose, apply Q or P;
  62. *          = 'C':  Conjugate transpose, apply Q**H or P**H.
  63. *
  64. *  M       (input) INTEGER
  65. *          The number of rows of the matrix C. M >= 0.
  66. *
  67. *  N       (input) INTEGER
  68. *          The number of columns of the matrix C. N >= 0.
  69. *
  70. *  K       (input) INTEGER
  71. *          If VECT = 'Q', the number of columns in the original
  72. *          matrix reduced by ZGEBRD.
  73. *          If VECT = 'P', the number of rows in the original
  74. *          matrix reduced by ZGEBRD.
  75. *          K >= 0.
  76. *
  77. *  A       (input) COMPLEX*16 array, dimension
  78. *                                (LDA,min(nq,K)) if VECT = 'Q'
  79. *                                (LDA,nq)        if VECT = 'P'
  80. *          The vectors which define the elementary reflectors H(i) and
  81. *          G(i), whose products determine the matrices Q and P, as
  82. *          returned by ZGEBRD.
  83. *
  84. *  LDA     (input) INTEGER
  85. *          The leading dimension of the array A.
  86. *          If VECT = 'Q', LDA >= max(1,nq);
  87. *          if VECT = 'P', LDA >= max(1,min(nq,K)).
  88. *
  89. *  TAU     (input) COMPLEX*16 array, dimension (min(nq,K))
  90. *          TAU(i) must contain the scalar factor of the elementary
  91. *          reflector H(i) or G(i) which determines Q or P, as returned
  92. *          by ZGEBRD in the array argument TAUQ or TAUP.
  93. *
  94. *  C       (input/output) COMPLEX*16 array, dimension (LDC,N)
  95. *          On entry, the M-by-N matrix C.
  96. *          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q
  97. *          or P*C or P**H*C or C*P or C*P**H.
  98. *
  99. *  LDC     (input) INTEGER
  100. *          The leading dimension of the array C. LDC >= max(1,M).
  101. *
  102. *  WORK    (workspace/output) COMPLEX*16 array, dimension (LWORK)
  103. *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
  104. *
  105. *  LWORK   (input) INTEGER
  106. *          The dimension of the array WORK.
  107. *          If SIDE = 'L', LWORK >= max(1,N);
  108. *          if SIDE = 'R', LWORK >= max(1,M).
  109. *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
  110. *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
  111. *          blocksize.
  112. *
  113. *  INFO    (output) INTEGER
  114. *          = 0:  successful exit
  115. *          < 0:  if INFO = -i, the i-th argument had an illegal value
  116. *
  117. *  =====================================================================
  118. *
  119. *     .. Local Scalars ..
  120.       LOGICAL            APPLYQ, LEFT, NOTRAN
  121.       CHARACTER          TRANST
  122.       INTEGER            I1, I2, IINFO, MI, NI, NQ, NW
  123. *     ..
  124. *     .. External Functions ..
  125.       LOGICAL            LSAME
  126.       EXTERNAL           LSAME
  127. *     ..
  128. *     .. External Subroutines ..
  129.       EXTERNAL           XERBLA, ZUNMLQ, ZUNMQR
  130. *     ..
  131. *     .. Intrinsic Functions ..
  132.       INTRINSIC          MAX, MIN
  133. *     ..
  134. *     .. Executable Statements ..
  135. *
  136. *     Test the input arguments
  137. *
  138.       INFO = 0
  139.       APPLYQ = LSAME( VECT, 'Q' )
  140.       LEFT = LSAME( SIDE, 'L' )
  141.       NOTRAN = LSAME( TRANS, 'N' )
  142. *
  143. *     NQ is the order of Q or P and NW is the minimum dimension of WORK
  144. *
  145.       IF( LEFT ) THEN
  146.          NQ = M
  147.          NW = N
  148.       ELSE
  149.          NQ = N
  150.          NW = M
  151.       END IF
  152.       IF( .NOT.APPLYQ .AND. .NOT.LSAME( VECT, 'P' ) ) THEN
  153.          INFO = -1
  154.       ELSE IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
  155.          INFO = -2
  156.       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
  157.          INFO = -3
  158.       ELSE IF( M.LT.0 ) THEN
  159.          INFO = -4
  160.       ELSE IF( N.LT.0 ) THEN
  161.          INFO = -5
  162.       ELSE IF( K.LT.0 ) THEN
  163.          INFO = -6
  164.       ELSE IF( ( APPLYQ .AND. LDA.LT.MAX( 1, NQ ) ) .OR.
  165.      $         ( .NOT.APPLYQ .AND. LDA.LT.MAX( 1, MIN( NQ, K ) ) ) )
  166.      $          THEN
  167.          INFO = -8
  168.       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
  169.          INFO = -11
  170.       ELSE IF( LWORK.LT.MAX( 1, NW ) ) THEN
  171.          INFO = -13
  172.       END IF
  173.       IF( INFO.NE.0 ) THEN
  174.          CALL XERBLA( 'ZUNMBR', -INFO )
  175.          RETURN
  176.       END IF
  177. *
  178. *     Quick return if possible
  179. *
  180.       WORK( 1 ) = 1
  181.       IF( M.EQ.0 .OR. N.EQ.0 )
  182.      $   RETURN
  183. *
  184.       IF( APPLYQ ) THEN
  185. *
  186. *        Apply Q
  187. *
  188.          IF( NQ.GE.K ) THEN
  189. *
  190. *           Q was determined by a call to ZGEBRD with nq >= k
  191. *
  192.             CALL ZUNMQR( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
  193.      $                   WORK, LWORK, IINFO )
  194.          ELSE IF( NQ.GT.1 ) THEN
  195. *
  196. *           Q was determined by a call to ZGEBRD with nq < k
  197. *
  198.             IF( LEFT ) THEN
  199.                MI = M - 1
  200.                NI = N
  201.                I1 = 2
  202.                I2 = 1
  203.             ELSE
  204.                MI = M
  205.                NI = N - 1
  206.                I1 = 1
  207.                I2 = 2
  208.             END IF
  209.             CALL ZUNMQR( SIDE, TRANS, MI, NI, NQ-1, A( 2, 1 ), LDA, TAU,
  210.      $                   C( I1, I2 ), LDC, WORK, LWORK, IINFO )
  211.          END IF
  212.       ELSE
  213. *
  214. *        Apply P
  215. *
  216.          IF( NOTRAN ) THEN
  217.             TRANST = 'C'
  218.          ELSE
  219.             TRANST = 'N'
  220.          END IF
  221.          IF( NQ.GT.K ) THEN
  222. *
  223. *           P was determined by a call to ZGEBRD with nq > k
  224. *
  225.             CALL ZUNMLQ( SIDE, TRANST, M, N, K, A, LDA, TAU, C, LDC,
  226.      $                   WORK, LWORK, IINFO )
  227.          ELSE IF( NQ.GT.1 ) THEN
  228. *
  229. *           P was determined by a call to ZGEBRD with nq <= k
  230. *
  231.             IF( LEFT ) THEN
  232.                MI = M - 1
  233.                NI = N
  234.                I1 = 2
  235.                I2 = 1
  236.             ELSE
  237.                MI = M
  238.                NI = N - 1
  239.                I1 = 1
  240.                I2 = 2
  241.             END IF
  242.             CALL ZUNMLQ( SIDE, TRANST, MI, NI, NQ-1, A( 1, 2 ), LDA,
  243.      $                   TAU, C( I1, I2 ), LDC, WORK, LWORK, IINFO )
  244.          END IF
  245.       END IF
  246.       RETURN
  247. *
  248. *     End of ZUNMBR
  249. *
  250.       END
  251.